"커먼리습 ASDF 불러오기 편하게 하기" 대모험

  (eval-when (:compile-toplevel :load-toplevel :execute)
    ;; 필요한 라이브러리들 로드.
    (ql:quickload :cl-fad)  ; 하위 디렉토리에서 파일 검색 & pathname 조작.
    (ql:quickload :cl-ppcre)  ; regex.
    (ql:quickload :closer-mop)  ; funcall-able metaclass.
    (ql:quickload :equals)  ; CLOS객체의 값 비교 protocol.

    ;; 로딩 하는 소스파일의 디렉토리.
    (defvar *my-dir* nil))

  (unless *my-dir*
    ;; 처음 소스파일을 컴파일, 로딩 할 때 세팅됨.
    (let* ((pn *load-pathname*)
           (dir (cl-fad:pathname-directory-pathname pn)))
      (setf *my-dir* dir)))

  ;;; cl-fad:walk-directory 으로 파일 검색 시 조기 중단을 위해 condition 정의.
  (define-condition cl-fad-matching-found (condition)
    ((found :initarg :found)))

  (defun find-asdf-in-subdir (dir asdf-name)
    "(find-asdf-in-subdir #p\"/home/my/project\" :cl-state-machine)
    ;; => #P\".../cl-state-machine.asd\" or NIL"
    (flet ((signal-found (found)  ; 검색에 성공해서 매칭 결과를 전달.
             (signal 'cl-fad-matching-found :found found)))
      (handler-bind ((cl-fad-matching-found  ; 검색 성공, 매칭 결과를 되돌리며 조기 종료.
                       #'(lambda (c) (with-slots (found) c
                                       (return-from find-asdf-in-subdir found)))))
        ;; `scanner' 으로 regex 매칭을 준비.
        (let ((scanner (cl-ppcre:create-scanner (format nil "~a\.asd(f)?"
                                                        (string asdf-name))
                                                ;; keyword->string하면 기본 설정이 대문자이므로.
                                                :case-insensitive-mode t)))
          (cl-fad:walk-directory dir
                                 (lambda (name)
                                   (let ((base-name (path:basename name)))
                                     (when (cl-ppcre:scan scanner (namestring base-name))
                                       ;; 매칭 성공.
                                       (signal-found name))))
                                 ;; 디렉토리 항목은 매칭 시도 안하도록.
                                 :directories nil)
          ;; not-found
          nil))))

  ;;; `funcallable-standard-class'을 metaclass으로 지정하여, closure으로
  ;;; finder함수를 감싸서 `asdf:*system-definition-search-functions*'
  ;;; 넣지 않도록 했다.
  ;;;
  ;;; closure이 아니라 그냥 CLOS object이므로 `equals:equals'을 구현하기
  ;;; 쉽도록. (또 common-lisp 구현에 따라서도 portable하기도 하고)
  ;;;
  ;;; http://www.metamodulaire.net/CLOS-MOP/funcallable-instances.html
  (defclass asdf-finder ()
    ((base-dir :initarg :base-dir))
    (:metaclass closer-mop:funcallable-standard-class))

  ;;; 반복적으로 `pushnew'해도 동일한 디렉토리에 대한, `asdf-finder'을
  ;;; 중복해서 넣지 않도록, `equals'-protocol을 구현.
  ;;;
  ;;; `pushnew'을 반복적으로 하게 되는 이유는, 같은 live image에
  ;;; 소스코드를 수정하며 컴파일을 반복적으로 하며 점진적으로 개발하는
  ;;; 사이클이 커먼리습에서는 편하니까, 그런 개발 사이클에 적합할 수
  ;;; 있도록 고려해서.
  (defmethod equals:equals ((lhs asdf-finder) (rhs asdf-finder) &rest args)
    (declare (ignore args))
    (equals:equals (slot-value lhs 'base-dir) (slot-value rhs 'base-dir)))

  ;;; 초기화가 끝난 다음에, funcallable한 객체로 만든다.
  (defmethod initialize-instance :after ((an-asdf-finder asdf-finder) &key)
    (with-slots (base-dir) an-asdf-finder
      ;;; `funcall' 이 이 인스턴스에 대해 적용될 때, 어떻게 동작할지.
      (closer-mop:set-funcallable-instance-function
       an-asdf-finder #'(lambda (asdf-name)
                          (find-asdf-in-subdir base-dir asdf-name)))))

  ;;; ASDF3에 연결.
  ;;;
  ;;; 현재 소스파일이 있는 디렉토리 이하에 있는 `*.asdf', `*.asdf' asdf
  ;;; system definition file을 자동으로 로딩한다.
  ;;;
  ;;; 예를 들어, `(asdf:load-system :cl-state-machine)' 을 시도하면,
  ;;; `cl-state-machine.asd' 이나 `cl-state-machine.asdf' 을 하위
  ;;; 디렉토리에서 검색해 로딩할 것이다.
  (pushnew (make-instance 'asdf-finder :base-dir *my-dir*)
           asdf:*system-definition-search-functions*
           :test #'equals:equals)

  ;; EX: (ql:quickload :cl-state-machine)
  ;; EX: (asdf:load-system :cl-state-machine)